Problem z portalem magazynowym

Question

Witam serdecznie,

Bardzo potrzebuję pomocy, a jestem kompletnie zielony z informatyki. Może znajdą się tu ludzie, którzy mi pomogą? Wierzę, że dobro wraca.  

Przeglądając YouTube znalazłem darmowy program do mojego małego sklepiku. Pobrałem go zgodnie z instrukcją, ściągając dodatkowo program "firebird". Niestety wyskakuje mi błąd z którego kompletnie nic nie rozumiem, oraz nie mogę nic o tym błędzie znaleźć w googlach.

Błąd brzmi następująco: "Exception EiBinterBase Error in module magazyn.exe at 0034a775. Unavailable database."

 

Wysyłam link do google drive z tym programem poniżej oraz filmik na YouTube, gdzie autor mówi o tym programie. (ma około 10mb tylko:))

https://drive.google.com/drive/folders/0B1Bn_rSTUFZteC1oWl9tdkRPcWc?resourcekey=0-1VhKA8gEoVGmUgjlSw1wBQ

https://www.youtube.com/watch?v=WcT_ULjyF0M&ab_channel=Delphiibazydanych

 

Bardzo będę wdzięczny za pomoc. Wierzę, że dobro wraca, dlatego temu kto mi pomoże niech los hojnie obdaruje.

Comments

wrzuć pliki dotyczące skanu "uploada", aby Ciktórzy będą pobierali :) na własne ryzyko mieli chociaż zabezpieczenie.

---

Wierzę, że dobro wraca.

Niestety, tylko karma wraca...:)

---

Pisz priv dzisiaj koło 12/13 to się zgadamy na discorda i spróbujemy ogarnąć co i jak :)

---

@tomar1212: dobra karma nie wraca, mój kot to potwierdza :)

Answer 1

Napisałeś

ściągając dodatkowo program "firebird"

rozumiem, że zainstalowałeś na swoim komputerze firebird-a.

Czy utworzyłeś folder Magazyn na dysku C i umieściłeś tam plik bazy danych MAGAZYN.FDB tak jak jest to opisane* przez autora w filmiku (46 minuta 40 sekunda) i tak jak jest to zapisane w pilku baza.ini

[baza]
database=127.0.0.1:C:\Magazyn\MAGAZYN.FDB
user_name=SYSDBA
password=masterkey
sql_role=
lc_ctype=UTF8

 

* - Autor nieco wprowadza w błąd oglądających, na filmie używa lokalizacji dla pliku bazy danych:
C:\baza\MAGAZYN.FDB

a w załączonym do programu pliku baza.ini domyślna lokalizacja jest
C:\Magazyn\MAGAZYN.FDB

nie podejrzewam tu złej woli autora a raczej przeoczenie. 

 

 

P.S.1. Baza danych (plik: MAGAZYN.FDB) może znajdować się w dowolnej lokalizacji (na komputerze, czy w sieci lokalnej), wymaga to jedynie ustawienia odpowiedniego wpisu w pliku baza.ini, wykonanego, czy to "ręcznie", czy za pomocą dołączonego małego programiku baza.exe.

 

P.S.2.Umieszczając plik bazy danych (MAGAZYN.FDB) w tym samym folderze co program (jak to ma miejsce po rozpakowaniu pobranego pliku Magazyn.zip) w pewnym sensie aplikacja może działać z pendirve-a.

Comments

P.S.2.Umieszczając plik bazy danych (MAGAZYN.FDB) w tym samym folderze co program (jak to ma miejsce po rozpakowaniu pobranego pliku Magazyn.zip) w pewnym sensie aplikacja może działać z pendirve-a.

Oczywiście trzeba się upewnieć, że literka przyporządkowana do pendrive jest zawsze ta sama - a może się zmienić jeśli np. jest inny pendrive już wcześniej podłączony.

---

Może autor programu doda taką funkcjonalność.

Podany niżej skrypt (vbs) uaktualnia w pliku: baza.ini, atrybut database o aktualną ścieżkę dostępu do pliku bazy danych  (MAGAZYN.FDB), gdy znajduje się w tym samym folderze co program, przydatne przy pierwszym uruchomieniu np. z pendirve-a.

 

update_to_current_folder_baza_ini.vbs

Option Explicit

Const FOR_READING = 1, FOR_WRITING = 2
Const OVERWRITE = True
Const DO_NOT_CREATE = False
Const DATABASE_INI_FILE = "baza.ini"
Const DATABASE_FDB_FILE = "MAGAZYN.FDB"
Const ATTRIBUTE_TO_FIND = "database="

Dim oFso, oShell, sApplicationFolderPath

Set oFso = CreateObject("Scripting.FileSystemObject")
Set oShell = CreateObject("Wscript.Shell")

sApplicationFolderPath = oShell.CurrentDirectory

If oFso.FileExists(DATABASE_INI_FILE) Then
  If oFso.FileExists(DATABASE_FDB_FILE) Then
    Dim oFile, sFileContext

    Set oFile = oFso.OpenTextFile(DATABASE_INI_FILE, FOR_READING, DO_NOT_CREATE)
    sFileContext = oFile.ReadAll
	oFile.Close
    
	If InStr(1, sFileContext, ATTRIBUTE_TO_FIND, vbTextCompare) Then
	  On Error Resume Next
	  Dim iPositionStart, iPositionEnd, sAttributeContext
	  
	  sAttributeContext = vbNullString
	  iPositionStart = InStr(1, sFileContext, ATTRIBUTE_TO_FIND, vbTextCompare) + Len(ATTRIBUTE_TO_FIND)
	  iPositionEnd = InStr(iPositionStart, sFileContext, vbCrLf, vbTextCompare)
	  sAttributeContext = Mid(sFileContext, iPositionStart, (iPositionEnd - iPositionStart))
	  sAttributeContext = Mid(sAttributeContext, InStr(1, sAttributeContext, ":", vbTextCompare) + 1)	  
	  
	  If Err.Number = 0 And Not sAttributeContext = vbNullString Then
	    sFileContext = Replace(sFileContext, sAttributeContext, oFso.BuildPath(sApplicationFolderPath, DATABASE_FDB_FILE))
        ' WScript.Echo sFileContext
		
		Set oFile = oFso.OpenTextFile(DATABASE_INI_FILE, FOR_WRITING, DO_NOT_CREATE)
		oFile.Write sFileContext
		oFile.Close
		
		If Err.Number = 0 Then
		  AttributeUpdatePrompt DATABASE_INI_FILE, DATABASE_INI_FILE
		Else
		  AttributeNotUpdatePrompt DATABASE_INI_FILE, DATABASE_INI_FILE
		End If
	  End If
	Else
	  AttributeExistsPrompt DATABASE_INI_FILE, DATABASE_INI_FILE, ATTRIBUTE_TO_FIND
	End If

  Else
    FileExistsPrompt DATABASE_FDB_FILE, DATABASE_FDB_FILE, sApplicationFolderPath
  End If
  
  Set oFile = Nothing
Else
  FileExistsPrompt DATABASE_INI_FILE, DATABASE_INI_FILE, sApplicationFolderPath
End If

Set oShell = Nothing
Set oFso = Nothing

Wscript.Quit

' *******************************************************************************

Sub FileExistsPrompt(sFile, sTitle, sFolder)
  Msgbox Space(5) & "Nie mozna odnalesc pliku:  " & sFile & vbCrLf & _
         Space(5) & "w biezacym folderze:  " & sFolder, _
         vbOKOnly + vbExclamation, "Update: " & sTitle
End Sub

Sub AttributeExistsPrompt(sFile, sTitle, sAttribute)
  Msgbox Space(5) & "Nie mozna odnalesc w pliku:  " & sFile & vbCrLf & _
         Space(5) & "atrybutu:  " & Replace(sAttribute, "=", vbNullString), _
         vbOKOnly + vbExclamation, "Update: " & sTitle
End Sub

Sub AttributeUpdatePrompt(sFile, sTitle)
  Msgbox Space(5) & "Plik:  " & sFile & vbCrLf & _
         Space(5) & "zostal zaktualizowany - poprawnie", _
         vbOKOnly + vbInformation, "Update: " & sTitle
End Sub

Sub AttributeNotUpdatePrompt(sFile, sTitle)
  Msgbox Space(5) & "Wystapil problem z aktualizacja pliku:  " & sFile, _
         vbOKOnly + vbCritical, "Update: " & sTitle
End Sub