Excel / Access VBA - nazwa aktualnej sieci

Question

Witam, czy jest możliwość uzyskania nazwy podłączonej lub wszystkich w pobliżu sieci WiFi przez VBA (Excel / Access)?
Z góry dziękuję za pomoc.

Answer 1

Możesz np. z poziomu VBA (Excel / Access) uruchomić polecenie dos-owe: netsh

netsh wlan show networks mode=bssid

 

przykład

Option Explicit

Sub wifi() ' przykładowa nazwa makra
    Dim objShell, objShellExec As Variant
    Dim strCmd, strOutput As String
    
    Set objShell = CreateObject("WScript.Shell")
    
    strCmd = "netsh wlan show networks mode=bssid"
    Set objShellExec = objShell.Exec(strCmd)

    strOutput = objShellExec.StdOut.ReadAll
    
    If Not strOutput = vbNullString Then
        Dim intIndex As Integer, arrOutput() As String
        
        MsgBox (strOutput)
        arrOutput = removeEmptyLines(strOutput)
        
        MsgBox arrOutput(2) ' nazwa sieci
        
        'For intIndex = 0 To UBound(arrOutput)
        '    MsgBox arrOutput(intIndex)
        'Next
    End If
End Sub

Function removeEmptyLines(strIn As String) As Variant
    If Len(strIn) > 0 Then
        Dim intIndex As Integer, strTemp, arrTemp() As String
        
        arrTemp = Split(strIn, vbNewLine)
        
        For intIndex = 0 To UBound(arrTemp)
            If Not Trim(arrTemp(intIndex)) = vbNullString Then
                strTemp = strTemp & arrTemp(intIndex) & ";"
            End If
        Next
        
        If Right(strTemp, 1) = ";" Then strTemp = Left(strTemp, Len(strTemp) - 1)
        removeEmptyLines = Split(strTemp, ";")
    Else
        removeEmptyLines = Empty
    End If
End Function

 

Sprawdź też: VBA - Obtain Wireless Network Name (Connected)

Comments

Działa! Bardzo dziękuję!