[Arduino] - zaprogramowanie jednego przycisku do kilku funkcji

Question

Witam,

Napisałem w symulatorze Arduino program symulujący zmianę trybu świecenie diod, cztery przyciski odpowiadają czterem trybom świecenia. Chciałbym zamienić te cztery przyciski na jeden ( każde następne kliknięcie to kolejny tryb świecenia diod). Nie mam pomysłu jak to zrobić. Bardzo proszę o pomoc. 

const int buttonPin1 = 2;
const int buttonPin2 = 3;
const int buttonPin3 = 4;
const int buttonPin4 = 5;  
const int ledPin1 =  13;
const int ledPin2 =  12;
const int ledPin3 =  11;  
const int ledPin4 =  10;    


int buttonState1 = 0;
int buttonState2 = 0;
int buttonState3 = 0;
int buttonState4 = 0;         

void setup() {
 
  pinMode(ledPin1, OUTPUT);
  pinMode(ledPin2, OUTPUT);
  pinMode(ledPin3, OUTPUT);
  pinMode(ledPin4, OUTPUT);
  
  pinMode(buttonPin1, INPUT);
  pinMode(buttonPin2, INPUT);
  pinMode(buttonPin3, INPUT);
  pinMode(buttonPin4, INPUT);
}

void loop() {
  
  buttonState1 = digitalRead(buttonPin1);
  buttonState2 = digitalRead(buttonPin2);
  buttonState3 = digitalRead(buttonPin3);
  buttonState4 = digitalRead(buttonPin4);

  
  if (buttonState1 == HIGH) {
    
    digitalWrite(ledPin1, HIGH);
    digitalWrite(ledPin2, HIGH);
    digitalWrite(ledPin3, HIGH);
    digitalWrite(ledPin4, HIGH);
  } else {
    
    digitalWrite(ledPin1, LOW);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, LOW);
    digitalWrite(ledPin4, LOW);

  }
  
  if(buttonState2 == HIGH){
    digitalWrite(ledPin1, HIGH);
    delay(500);
    digitalWrite(ledPin1, LOW);
    digitalWrite(ledPin2, HIGH);
    delay(500);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, HIGH);
    delay(500);
    digitalWrite(ledPin3, LOW);
    digitalWrite(ledPin4, HIGH);
    delay(500);
    digitalWrite(ledPin4, LOW);
  }else{
    digitalWrite(ledPin1, LOW);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, LOW);
    digitalWrite(ledPin4, LOW);
  }
  

  if(buttonState3 == HIGH){
    digitalWrite(ledPin1, HIGH);
    delay(100);
    digitalWrite(ledPin1, LOW);
   digitalWrite(ledPin2, HIGH);
    delay(110);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, HIGH);
    delay(100);
    digitalWrite(ledPin3, LOW);
    digitalWrite(ledPin4, HIGH);
    delay(110);
    digitalWrite(ledPin4, LOW);
  
  }else{
    digitalWrite(ledPin1, LOW);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, LOW);
    digitalWrite(ledPin4, LOW);
  }

  if (buttonState4 == HIGH) {
    
    digitalWrite(ledPin1, HIGH);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, HIGH);
    digitalWrite(ledPin4, LOW);
    delay(1000);
    digitalWrite(ledPin1, LOW);
    digitalWrite(ledPin2, HIGH);
    digitalWrite(ledPin3, LOW);
    digitalWrite(ledPin4, HIGH);
    delay(1000);
    digitalWrite(ledPin1, HIGH);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, HIGH);
    digitalWrite(ledPin4, LOW);
    
  } else {
    
    digitalWrite(ledPin1, LOW);
    digitalWrite(ledPin2, LOW);
    digitalWrite(ledPin3, LOW);
    digitalWrite(ledPin4, LOW);

  }



}

 

Answer 1

Może dodaj zmienną, coś na wzór licznika kliknięć.  

 

[ UPDATE ]

przykład  [ on-line ]

const byte BUTTON_PIN = 2; 
const byte LEDS_PIN[5] = { 13, 12, 11, 10, 9 };
const byte LEDS_PIN_REVERS[5] = { 9, 10, 11, 12, 13 };
const byte LEDS_PIN_COUNT = 5;
const byte MAX_MODE = 6;


void setup() {
  //Serial.begin(115200);
  for (byte led: LEDS_PIN)
    pinMode(led, OUTPUT);
   
  pinMode(BUTTON_PIN, INPUT_PULLUP);
}

byte buttonLastState = LOW;
byte mode = 0;

void loop() {
  byte buttonCurrentState = digitalRead(BUTTON_PIN);

  if (buttonLastState != buttonCurrentState) {
    buttonLastState = buttonCurrentState;

    if (buttonCurrentState == LOW) {
      mode += 1;
      if (mode > MAX_MODE) mode = 0;
      //Serial.println(mode);
    }
  }

  switch (mode) {
    case 1: ledLightsSolid(); break;
    case 2: ledLightsOff(); ledLightsBlinkInLine(); break;
    case 3: ledLightsOff(); ledLightsBlinkInLineRevers(); break;
    case 4: ledLightsOff(); ledLightsBlinkInPingPong(); break;
    case 5: ledLightsFadeInOut(); break;
    case 6: ledLightsFromMiddleSolid(); break;       
    default: ledLightsOff(); // mode = 0
  }
}

void ledLightsOff() {
  for (byte led: LEDS_PIN)
    digitalWrite(led, LOW);    
}

void ledLightsSolid() {
  for (byte led: LEDS_PIN)
    digitalWrite(led, HIGH);  
}

void ledLightsBlinkInLine() {
  for (byte led: LEDS_PIN) {
    digitalWrite(led, HIGH); 
    if (delayLoop(150)) return;
    digitalWrite(led, LOW);
  }   
}

void ledLightsBlinkInLineRevers() {  
  for (byte led: LEDS_PIN_REVERS) {
    digitalWrite(led, HIGH); 
    if (delayLoop(150)) return;
    digitalWrite(led, LOW);
  }   
}

void ledLightsBlinkInPingPong() {
  ledLightsBlinkInLine();
  ledLightsBlinkInLineRevers();
}

void ledLightsFadeInOut() {
  ledLightsOff();
  if (delayLoop(200)) return;
  ledLightsSolid();
  if (delayLoop(500)) return;  
}

void ledLightsFromMiddleSolid() {
  byte middle = (byte) LEDS_PIN_COUNT / 2;

  ledLightsOff();
  if (delayLoop(200)) return;
  digitalWrite(LEDS_PIN[middle], HIGH);
  if (delayLoop(200)) return;

  for (byte i=1; i<=middle; i++) {
    digitalWrite(LEDS_PIN[middle - i], HIGH);
    digitalWrite(LEDS_PIN[middle + i], HIGH);
    if (delayLoop(200)) return;
  }

  if (delayLoop(500)) return;  
}

boolean delayLoop(unsigned int delayInterval) {
  unsigned long startMillis = millis();

  do {
    if (digitalRead(BUTTON_PIN) == LOW) return true;
  } while (millis() - startMillis < delayInterval);

  return false;
}

 

 

P.S. Blink Without delay()

Comments

Bardzo dziękuje za pomoc. :)

---

[ UPDATE ]