Skrypt z WSH połączony z informacjami systemowymi (a także ich zapisywaniem do pliku)

Question

Hej :)

Mam do wykonania takie dwa o to zadanka:

1.Napisz skrypt wyświetlający Architekturę, identyfikator oraz wersję procesora (pobierz informację ze zmiennych systemowych)
2.Zmodyfikuj powyższy skrypt aby wszystkie informacje zapisał do pliku tekstowego

Kompletnie nie mam pojęcia jak to rozpisać. Wcześniejsze zadanie to było de facto wypisanie liczb pierwszych mniejszych niż 100 (czyli banał dla zapoznania z językiem), a teraz po skąpej treści teoretycznej taka wrzutka.  Wiem, że muszę się posłużyć w tym zadaniach obiektami. Z góry dziękuję za wszelkie odpowiedzi.  

EDIT

Okej, na tą chwilę mam tyle do pierwszego zadania:

Dim WshShell
Dim WshProcEnv
Dim process_architecture
Dim process_identifier
Dim process_revision


Set WshShell =  CreateObject("WScript.Shell")
Set WshProcEnv = WshShell.Environment("Process")

process_architecture= WshProcEnv("PROCESSOR_ARCHITECTURE") 
process_identifier = WshProcEnv("PROCESSOR_IDENTIFIER")
process_revision = WshProcEnv("PROCESSOR_REVISION")

MsgBox "Type of CPU on the computer: " & process_architecture & vbCrLf & "Type of ID: " & process_identifier & vbCrLf & "Version of the CPU: " & process_revision

Czy jest to dobrze zapisane? Jeśli tak jak mogę teraz zapisać to do pliku?

 

Answer 1

Dim WshShell
Dim WshProcEnv
Dim objFSO, objFile
Dim file_name
Dim process_architecture
Dim process_identifier
Dim process_revision
Dim raport

Const OVER_WRITE = True


Set WshShell =  CreateObject("Wscript.Shell")
Set WshProcEnv = WshShell.Environment("Process")
Set objFSO = CreateObject("Scripting.FileSystemObject")

process_architecture= WshProcEnv("PROCESSOR_ARCHITECTURE")
process_identifier = WshProcEnv("PROCESSOR_IDENTIFIER")
process_revision = WshProcEnv("PROCESSOR_REVISION")

raport = "Type of CPU on the computer: "  & process_architecture & vbCrLf & _
         "Type of ID: "  & process_identifier & vbCrLf & _
         "Version of the CPU: "  & process_revision

MsgBox  raport, vbOKOnly + vbInformation , "Information about the processor"

file_name = objFSO.BuildPath(WshShell.CurrentDirectory,"dane.txt")
Set objFile = objFSO.CreateTextFile(file_name, OVER_WRITE)
    objFile.WriteLine(raport)
    objFile.Close